Desde hace ya varias versiones Microsoft ha introducido la capacidad de sus productos de Office de traducir palabras en diversos idiomas. Por supuesto que eso incluye al Excel.
:
Dicha herramienta hace uso de lo servicios de traducción de Microsoft, los cuales se incluyen como para de la suite Office (dentro de los programas), pero son de pago si se quiere acceder, por ejemplo, desde las macros (VBA) para personalizarlas de algún modo.
Una alternativa a ellos es usar Google Traductor que, si bien ha cambiado su interfase de internet y la actual dificulta un poco el acceso, no es imposible lograrlo. Por cierto, es necesario tener acceso a internet, así como tener el navegador Internet Explorer instalado (todos los Windows lo tienen, incluso el 10, así sea el Edge el predeterminado, por si acaso).
Entonces, ahora quiero comentar que he usado el objeto Internet Explorer dado que es más fácil su uso, aunque acepto que para hacer Web Scraping (o similares) es más rápido usar MSXML2 (lo usaré en una próxima oportunidad).
Ahora sí, manos a la obra. Lo primero es comentarles que inicialmente pensé en detectar los elementos/objetos de la web del traductor (Enlace) y enviar el texto a traducir para que ellos ocurra de modo automático en los idiomas predeterminados ¿cuál era el dilema con eso? Pues elegir algún otro idioma, a través de las listas respectivas en dicha web, suponía una dificultad cuya programación, además de costar buen tiempo, no necesariamente iba a ser de fácil entendimiento. Decidido eso opte por usar otro método que se me ocurrió al observar el enlace que se genera cuando uno ingresa algún texto que desea traducir ¿cómo es eso? Pongamos por ejemplo la palabra “Hola”.
¿Notan lo qué ocurre? Veámoslo con más detenimiento:
https://translate.google.com/#view=home&op=translate&sl=es&tl=en&text=Hola
Si aún no lo notan, cambien la palabra por “Adiós” y obtendrán esto:
https://translate.google.com/#view=home&op=translate&sl=es&tl=en&text=Adios
“sl” por “star Lenguage” y “lt” por “translated language” y después del “Text=” el texto a traducir. En el caso de los idiomas, no fue difícil darse cuenta que respondía al código de idiomas según ISO 639-1 (Enlace). Hallado eso, se me ocurrió que, mandando desde el Excel el enlace con la combinación de idiomas necesario más el texto requerido, pues daría como resultado dicho texto traducido y aquel podría extraerse de la web. Igual antes hice unas pruebas con signos diversos a ver si significaban algún dilema. Para que se entienda, ingresen esto “Hola ¿cómo estás? Yo bien, espero tú igual” (sin las comillas) y el enlace será el siguiente:
https://translate.google.com/#view=home&op=translate&sl=es&tl=en&text=Hola%20¿cómo%20estás%3F%20Yo%20bien%2C%20espero%20tú%20igual
Como se aprecia, los espacios en blanco y algunos caracteres son reemplazados por su correspondiente código hexadecimal precedido de un signo “%”. Después de algunas pruebas, pude ver cuáles eran y los coloqué en una hoja que llamé “Signos”, del siguiente modo:
He omitido ahí el signo de porcentaje (%) y el de interrogación de cierre (¿), ya explicaré el por qué. Del mismo modo elegí algunos de los idiomas y los coloqué así en la misma hoja:
En una hoja que he llamado “Traductor” vamos a usar la celda A2 para ingresar el texto a traducir; si bien Google Traductor permite hasta 5000 caracteres, por una cuestión de orden vamos a poner un límite de 4000 en nuestro libro. En C2 y D2 incluiremos listas desplegables de validación basadas en la columna F de la hoja “Signos”, la única diferencia es que en C” incluiremos “Automático” y en D2 no, de ese modo de necesitar traducir un texto cuyo idioma se desconoce, basta usar dicha opción para que Google Traductor lo detecte.
Si bien el texto a cambiar lo vamos a colocar en A2, para luego cambiar, lo correspondiente, a código hexadecimal, enviaremos todo a F1.
Dim MiHoja As Worksheet
Set MiHoja = Worksheets("Traductor")
MiHoja.Range("F1").Value = MiHoja.Range("A2").Value
Luego convertiremos los caracteres necesarios de F1 en código hexadecimal. Vamos a comenzar por los signos de porcentaje (%) primero usando Replace, ya que el código hexadecimal debe ir precedido de dicho signo en cada caso y entonces es mejor cambiarlo(s) primero pues si se hace a la par de lo demás (con un bucle, como usaremos), podría reemplazarse todo lo que sí necesitaremos para enviar en el enlace que del traductor.
With MiHoja.Range("F1")
.Replace What:="%", Replacement:="%25", LookAt:=xlPart, _
SearchOrder:=xlByRows
25 es el hexadecimal del signo %, y obviamente también debe ir precedido de ese mismo signo (%).
Luego, igualmente usando Replace, con un bucle (For Each) recorreremos todos los códigos de los caracteres que deseamos reemplazar en la celda F1 y los convertiremos en hexadecimales precedidos de %.
For Each Celda In Worksheets("Signos").Range("C2:C20")
.Replace What:=ChrW(Celda.Value), Replacement:="%" & Celda.Offset(0, -2).Value, LookAt:=xlPart, _
SearchOrder:=xlByRows
Next Celda
Por último, haremos los mismo con el signo ?. Lo dejamos al último dado que puede ser confundido por Excel y/o VBA como un comodín y hacer que cambie todo el texto por él.
.Replace What:="~?", Replacement:="%3F", LookAt:=xlPart, _
SearchOrder:=xlByRows
End With
Para los idiomas haremos algo parecido, pero usando Find para encontrar el(los) elegidos y su diminutivo dado que eso último es lo que enviaremos al enlace de la web. Para ello usaremos dos variables.
'El uso de Let no es necesario, se puede dar el valor sin usarlo (es equivalente), pero
'tengo la costumbre de dejarlo. Igual, en casos como este se puede omitir Value, pero
'considero que colocarlo permite entender mejor a que propiedad se hace referencia
Dim CeldaaEncontrar As Range
Dim ValoraBuscar$, PrimerIdioma$, SegundoIdioma$
Let ValoraBuscar = MiHoja.Range("C2").Value
Set CeldaaEncontrar = Worksheets("Signos").Range("F2:F62").Find(ValoraBuscar)
Let PrimerIdioma = CeldaaEncontrar.Offset(0, 1).Value
Let ValoraBuscar = MiHoja.Range("D2").Value
Set CeldaaEncontrar = Worksheets("Signos").Range("F3:F62").Find(ValoraBuscar)
Let SegundoIdioma = CeldaaEncontrar.Offset(0, 1).Value
Hasta aquí ya tenemos el texto con los caracteres convertidos en hexadecimal (en F1) y en variables los diminutivos de los idiomas, aquí lo que hay que hacer es usar el objeto Internet Explorer, que abra la web del traductor con toda la cadena necesaria y con eso lograremos que lo traduzca.
Dim IE As Object
Set IE = CreateObject("InternetExplorer.Application")
With IE
.Navigate "https://translate.google.com/#view=home&op=translate&sl=" & PrimerIdioma & "&tl=" & SegundoIdioma & "&text=" & MiHoja.Range("F1").Value
Do Until .ReadyState = 4
DoEvents
Loop
End With
Como ven, he incluido un bucle que de tiempo para que cargue de forma correcta y de ese modo tener la traducción. Para finalizar solo queda extraer dicha traducción y enviarla a nuestra celda A5, borrar F1, proteger la hoja y cerrar el Internet Explorer (si bien nunca se verá el navegador, sí se abre).
With MiHoja
.Range("A5").Value = IE.document.querySelector(".tlid-translation.translation").innerText
.Range("F1").ClearContents
.Protect "1234"
End With
IE.Quit
Y listo, ya tenemos nuestro traductor de Google en nuestro archivo de Excel. La macro completa quedará así:
Sub Traductor ()
Dim Celda As Range, CeldaaEncontrar As Range
Dim IE As Object
Dim MiHoja As Worksheet
Dim ValoraBuscar$, PrimerIdioma$, SegundoIdioma$
Set MiHoja = Worksheets("Traductor")
If MiHoja.Range("A2") = "" Or MiHoja.Range("C2") = "" Or MiHoja.Range("D2") = "" Then
MsgBox "No debe dejar vacío los campos del texto a traducir o los idiomas", vbOKOnly, "Todos Sobre Excel"
Exit Sub
End If
If Len(MiHoja.Range("A2")) >= 4000 Then
MsgBox "No debes exceder de 4000 caracteres, por favor cambiar. Tienes " & Len(MiHoja.Range("A2")) & " caracteres en este momento", vbOKOnly, "Todos Sobre Excel"
Exit Sub
End If
Application.ScreenUpdating = False
MiHoja.Unprotect "1234"
MiHoja.Range("F1").Value = MiHoja.Range("A2").Value
With MiHoja.Range("F1")
'Convertimos los signos % a hexadecimal, lo hacemos antes de los demás ya que % es un signo usado
'varias veces y entraríamos casi en un bucle de convertirlo junto con todos los otros signos
.Replace What:="%", Replacement:="%25", LookAt:=xlPart, _
SearchOrder:=xlByRows
'en este bucle convertimos los signos a hexadecimal
For Each Celda In Worksheets("Signos").Range("C2:C20")
.Replace What:=ChrW(Celda.Value), Replacement:="%" & Celda.Offset(0, -2).Value, LookAt:=xlPart, _
SearchOrder:=xlByRows
Next Celda
'aquí lo hacemos con el signo ?, ya que si se usa el Replace junto con los demás signos y este, en un bucle, transforma todo
.Replace What:="~?", Replacement:="%3F", LookAt:=xlPart, _
SearchOrder:=xlByRows
End With
'El uso de Let no es necesario, se puede dar el valor sin usarlo (es equivalente), pero
'tengo la costumbre de dejarlo. Igual, en casos como este se puede omitir Value, pero
'considero que colocarlo permite entender mejor a que propiedad se hace referencia
Let ValoraBuscar = MiHoja.Range("C2").Value
Set CeldaaEncontrar = Worksheets("Signos").Range("F2:F62").Find(ValoraBuscar)
Let PrimerIdioma = CeldaaEncontrar.Offset(0, 1).Value
Let ValoraBuscar = MiHoja.Range("D2").Value
Set CeldaaEncontrar = Worksheets("Signos").Range("F3:F62").Find(ValoraBuscar)
Let SegundoIdioma = CeldaaEncontrar.Offset(0, 1).Value
Set IE = CreateObject("InternetExplorer.Application")
With IE
.Navigate "https://translate.google.com/#view=home&op=translate&sl=" & PrimerIdioma & "&tl=" & SegundoIdioma & "&text=" & MiHoja.Range("F1").Value
Do Until .ReadyState = 4
DoEvents
Loop
End With
With MiHoja
.Range("A5").Value = IE.document.querySelector(".tlid-translation.translation").innerText
.Range("F1").ClearContents
.Protect "1234"
End With
IE.Quit
'En módulos estándar no es necesario colocar en True el ScreenUpdating ya que con el
'End Sub lo hace, pero es mi costumbre de programador colocarlo
Application.ScreenUpdating = True
'Asimismo, el End Sub libera las variables, pero siempre uso el Nothing por costumbre
Set CeldaaEncontrar = Nothing: Set MiHoja = Nothing: Set IE = Nothing
MsgBox "Traducción realizada", vbOKOnly, "Todos Sobre Excel"
End Sub
Espero les guste, hasta la próxima.
Abraham Valencia
Descargue el ejemplo aquí
.
.
